home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / biblio / bibtex / contrib / germbib / bst / gerunsrt.bst < prev   
Text File  |  1993-04-20  |  21KB  |  1,060 lines
  1. % BibTeX standard bibliography style `plain'
  2.         % version 0.99a for BibTeX versions 0.99a or later, LaTeX version 2.09.
  3.         % Copyright (C) 1985, all rights reserved.
  4.         % Copying of this file is authorized only if either
  5.         % (1) you make absolutely no changes to your copy, including name, or
  6.         % (2) if you do make changes, you name it something other than
  7.         % btxbst.doc, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
  8.         % This restriction helps ensure that all standard styles are identical.
  9.         % The file btxbst.doc has the documentation for this style.
  10. %   15-feb-92   (MW)    Updated for use with `bibgerman.sty': things like "and"
  11. %                       change with the language. Switch the language using the
  12. %                       language field: 
  13. %                          language = "german" | "USenglish" | "english"
  14. %                       Then a `\selectlanguage{...}' command will be pushed just
  15. %                       before the `\bibitem...' command for the entry in work.
  16.  
  17. ENTRY
  18.   { address
  19.     author
  20.     booktitle
  21.     chapter
  22.     edition
  23.     editor
  24.     howpublished
  25.     institution
  26.     journal
  27.     key
  28.     language
  29.     month
  30.     note
  31.     number
  32.     organization
  33.     pages
  34.     publisher
  35.     school
  36.     series
  37.     title
  38.     type
  39.     volume
  40.     year
  41.   }
  42.   {}
  43.   { label }
  44.  
  45. INTEGERS { output.state before.all mid.sentence after.sentence after.block before.title }
  46.  
  47. STRINGS { s t language.state language.temp }
  48.  
  49. FUNCTION {init.state.consts}
  50. { #0 'before.all :=
  51.   #1 'mid.sentence :=
  52.   #2 'after.sentence :=
  53.   #3 'after.block :=
  54.   #4 'before.title :=
  55.   "nostate" 'language.state :=
  56. }
  57.  
  58. FUNCTION {language.state.test}
  59. { 
  60.   'language.temp :=
  61.   language.temp language.state =
  62.     { #1 }
  63.     { #0 }
  64.   if$
  65. }
  66.  
  67.  
  68. FUNCTION {not}
  69. {   { #0 }
  70.     { #1 }
  71.   if$
  72. }
  73.  
  74. FUNCTION {and}
  75. {   'skip$
  76.     { pop$ #0 }
  77.   if$
  78. }
  79.  
  80. FUNCTION {or}
  81. {   { pop$ #1 }
  82.     'skip$
  83.   if$
  84. }
  85.  
  86. FUNCTION {output.nonnull}
  87. { 's :=
  88.   output.state mid.sentence =
  89.     { ", " * write$ }
  90.     { output.state after.block =
  91.         { add.period$ write$
  92.           newline$
  93.           "\newblock " write$
  94.         }
  95.         { output.state before.all =
  96.             'write$
  97.             % next if is for use with `new' FUNCTION {after.authors}
  98.             { output.state before.title =
  99.                 { ": " * write$ }
  100.                 { add.period$ " " * write$ }
  101.               if$
  102.             }
  103.           if$
  104.         }
  105.       if$
  106.       mid.sentence 'output.state :=
  107.     }
  108.   if$
  109.   s
  110. }
  111.  
  112. FUNCTION {output}
  113. { duplicate$ empty$
  114.     'pop$
  115.     'output.nonnull
  116.   if$
  117. }
  118.  
  119. FUNCTION {output.check}
  120. { 't :=
  121.   duplicate$ empty$
  122.     { pop$ "empty " t * " in " * cite$ * warning$ }
  123.     'output.nonnull
  124.   if$
  125. }
  126.  
  127. FUNCTION {output.bibitem}
  128. { newline$
  129.   language empty$
  130.     'skip$
  131.     { language.state language =
  132.         'skip$
  133.         { "\selectlanguage{\" language * "}" * write$
  134.           newline$
  135.         }
  136.       if$
  137.       language 'language.state :=
  138.     }
  139.   if$
  140.   "\bibitem{" write$
  141.   cite$ write$
  142.   "}" write$
  143.   newline$
  144.   ""
  145.   before.all 'output.state :=
  146. }
  147.  
  148. FUNCTION {fin.entry}
  149. { add.period$
  150.   write$
  151.   newline$
  152. }
  153.  
  154. FUNCTION {new.block}
  155. { output.state before.all =
  156.     'skip$
  157.     { after.block 'output.state := }
  158.   if$
  159. }
  160.  
  161. FUNCTION {new.sentence}
  162. { output.state after.block =
  163.     'skip$
  164.     { output.state before.all =
  165.         'skip$
  166.         { after.sentence 'output.state := }
  167.       if$
  168.     }
  169.   if$
  170. }
  171.  
  172. % new one -> sets what is specified in FUNCTION {output.nonnull}
  173. % if `before.title 'output.state = ... if$' is true
  174. FUNCTION {after.authors}
  175. { output.state before.all =
  176.     'skip$
  177.     { before.title 'output.state := }
  178.   if$
  179. }
  180.  
  181. FUNCTION {new.block.checka}
  182. { empty$
  183.     'skip$
  184.     'new.block
  185.   if$
  186. }
  187.  
  188. FUNCTION {new.block.checkb}
  189. { empty$
  190.   swap$ empty$
  191.   and
  192.     'skip$
  193.     'new.block
  194.   if$
  195. }
  196.  
  197. FUNCTION {new.block.checkc}
  198. { empty$
  199.   swap$ empty$
  200.   and
  201.     'skip$
  202.     'after.authors
  203.   if$
  204. }
  205.  
  206. FUNCTION {new.sentence.checka}
  207. { empty$
  208.     'skip$
  209.     'new.sentence
  210.   if$
  211. }
  212.  
  213. FUNCTION {new.sentence.checkb}
  214. { empty$
  215.   swap$ empty$
  216.   and
  217.     'skip$
  218.     'new.sentence
  219.   if$
  220. }
  221.  
  222. FUNCTION {field.or.null}
  223. { duplicate$ empty$
  224.     { pop$ "" }
  225.     'skip$
  226.   if$
  227. }
  228.  
  229. FUNCTION {emphasize}
  230. { duplicate$ empty$
  231.     { pop$ "" }
  232.     { "{\em " swap$ * "}" * }
  233.   if$
  234. }
  235.  
  236. FUNCTION {smallcaps}
  237. { duplicate$ empty$
  238.     { pop$ "" }
  239.     { "{\sc " swap$ * "}" * }
  240.   if$
  241. }
  242.  
  243. INTEGERS { nameptr namesleft numnames }
  244.  
  245. FUNCTION {format.names}
  246. { 's :=
  247.   #1 'nameptr :=
  248.   s num.names$ 'numnames :=
  249.   numnames 'namesleft :=
  250.     { namesleft #0 > }
  251.     { nameptr #1 >
  252.         { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ smallcaps 't :=
  253.           namesleft #1 >
  254.             { ", " * t * }
  255.             { numnames #2 >
  256.                 { "english" language.state.test
  257.                   "USenglish" language.state.test
  258.                   or
  259.                      {"," * }
  260.                      'skip$
  261.                   if$
  262.                 }
  263.                 'skip$
  264.               if$
  265.               t "others" =
  266.                 { " \btxetalshort{.}" * }
  267.                 { " \btxandlong{}\ " * t * }
  268.               if$
  269.             }
  270.           if$
  271.         }
  272.         { s nameptr "{ll}{, jj}{, ff}{~vv}" format.name$ smallcaps }
  273.       if$
  274.       nameptr #1 + 'nameptr :=
  275.       namesleft #1 - 'namesleft :=
  276.     }
  277.   while$
  278. }
  279.  
  280. FUNCTION {format.authors}
  281. { author empty$
  282.     { "" }
  283.     { author format.names }
  284.   if$
  285. }
  286.  
  287. FUNCTION {format.editors}
  288. { editor empty$
  289.     { "" }
  290.     { editor format.names
  291.       editor num.names$ #1 >
  292.         { "\ (\btxeditorslong{})" * }
  293.         { "\ (\btxeditorlong{})" * }
  294.       if$
  295.     }
  296.   if$
  297. }
  298.  
  299. FUNCTION {format.title}
  300. { title empty$
  301.     { "" }
  302.     { "english" language.state.test
  303.       "USenglish" language.state.test
  304.       or
  305.         { title "t" change.case$ emphasize }
  306.         { title emphasize }
  307.       if$
  308.     }
  309.   if$
  310. }
  311.  
  312. FUNCTION {n.dashify}
  313. { 't :=
  314.   ""
  315.     { t empty$ not }
  316.     { t #1 #1 substring$ "-" =
  317.         { t #1 #2 substring$ "--" = not
  318.             { "--" *
  319.               t #2 global.max$ substring$ 't :=
  320.             }
  321.             {   { t #1 #1 substring$ "-" = }
  322.                 { "-" *
  323.                   t #2 global.max$ substring$ 't :=
  324.                 }
  325.               while$
  326.             }
  327.           if$
  328.         }
  329.         { t #1 #1 substring$ *
  330.           t #2 global.max$ substring$ 't :=
  331.         }
  332.       if$
  333.     }
  334.   while$
  335. }
  336.  
  337. FUNCTION {format.date}
  338. { year empty$
  339.     { month empty$
  340.         { "" }
  341.         { "there's a month but no year in " cite$ * warning$
  342.           month
  343.         }
  344.       if$
  345.     }
  346.     { month empty$
  347.         'year
  348.         { month " " * year * }
  349.       if$
  350.     }
  351.   if$
  352. }
  353.  
  354. FUNCTION {format.btitle}
  355. { title emphasize
  356. }
  357.  
  358. FUNCTION {tie.or.space.connect}
  359. { duplicate$ text.length$ #3 <
  360.     { "~" }
  361.     { "\ " }
  362.   if$
  363.   swap$ * *
  364. }
  365.  
  366. FUNCTION {either.or.check}
  367. { empty$
  368.     'pop$
  369.     { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  370.   if$
  371. }
  372.  
  373. FUNCTION {format.bvolume}
  374. { volume empty$
  375.     { "" }
  376.     { output.state after.block =
  377.         { "\Btxvolumelong{}" }
  378.         { "\btxvolumelong{}" }
  379.       if$
  380.       volume tie.or.space.connect
  381.       series empty$
  382.         'skip$
  383.         { " \btxofserieslong{}\ " * series emphasize * }
  384.       if$
  385.       "volume and number" number either.or.check
  386.     }
  387.   if$
  388. }
  389.  
  390. FUNCTION {format.number.series}
  391. { volume empty$
  392.     { number empty$
  393.         { series field.or.null }
  394.         { output.state mid.sentence =
  395.             { "\btxnumberlong{}" }
  396.             { "\Btxnumberlong{}" }
  397.           if$
  398.           number tie.or.space.connect
  399.           series empty$
  400.             { "there's a number but no series in " cite$ * warning$ }
  401.             { " \btxinserieslong{}\ " * series emphasize * }
  402.           if$
  403.         }
  404.       if$
  405.     }
  406.     { "" }
  407.   if$
  408. }
  409.  
  410. FUNCTION {format.edition}
  411. { edition empty$
  412.     { "" }
  413.     { "english" language.state.test
  414.       "USenglish" language.state.test
  415.       or
  416.         { output.state mid.sentence =
  417.             { edition "l" change.case$ " \btxeditionlong{}" * }
  418.             { edition "t" change.case$ " \btxeditionlong{}" * }
  419.           if$
  420.         }
  421.         { edition " \btxeditionlong{}" * }
  422.       if$
  423.     }
  424.   if$
  425. }
  426.  
  427. INTEGERS { multiresult }
  428.  
  429. FUNCTION {multi.page.check}
  430. { 't :=
  431.   #0 'multiresult :=
  432.     { multiresult not
  433.       t empty$ not
  434.       and
  435.     }
  436.     { t #1 #1 substring$
  437.       duplicate$ "-" =
  438.       swap$ duplicate$ "," =
  439.       swap$ "+" =
  440.       or or
  441.         { #1 'multiresult := }
  442.         { t #2 global.max$ substring$ 't := }
  443.       if$
  444.     }
  445.   while$
  446.   multiresult
  447. }
  448.  
  449. FUNCTION {format.pages}
  450. { pages empty$
  451.     { "" }
  452.     { pages multi.page.check
  453.         { "\btxpageslong{}" pages n.dashify tie.or.space.connect }
  454.         { "\btxpagelong{}" pages tie.or.space.connect }
  455.       if$
  456.     }
  457.   if$
  458. }
  459.  
  460. FUNCTION {format.vol.num.pages}
  461. { volume field.or.null
  462.   number empty$
  463.     'skip$
  464.     { "(" number * ")" * *
  465.       volume empty$
  466.         { "there's a number but no volume in " cite$ * warning$ }
  467.         'skip$
  468.       if$
  469.     }
  470.   if$
  471.   pages empty$
  472.     'skip$
  473.     { duplicate$ empty$
  474.         { pop$ format.pages }
  475.         { ":" * pages n.dashify * }
  476.       if$
  477.     }
  478.   if$
  479. }
  480.  
  481. FUNCTION {format.chapter.pages}
  482. { chapter empty$
  483.     'format.pages
  484.     { type empty$
  485.         { "\btxchapterlong{}" }
  486.         { "english" language.state.test
  487.           "USenglish" language.state.test
  488.           or
  489.              { type "l" change.case$ }
  490.              { type }
  491.          if$
  492.         }
  493.       if$
  494.       chapter tie.or.space.connect
  495.       pages empty$
  496.         'skip$
  497.         { ", " * format.pages * }
  498.       if$
  499.     }
  500.   if$
  501. }
  502.  
  503. FUNCTION {format.in.ed.booktitle}
  504. { booktitle empty$
  505.     { "" }
  506.     { editor empty$
  507.         { "\Btxinlong{}\ " booktitle emphasize * }
  508.         { "\Btxinlong{}\ " format.editors * ": " * booktitle emphasize * }
  509.       if$
  510.     }
  511.   if$
  512. }
  513.  
  514. FUNCTION {empty.misc.check}
  515. { author empty$ title empty$ howpublished empty$
  516.   month empty$ year empty$ note empty$
  517.   and and and and and
  518.     { "all relevant fields are empty in " cite$ * warning$ }
  519.     'skip$
  520.   if$
  521. }
  522.  
  523. FUNCTION {format.thesis.type}
  524. { type empty$
  525.     'skip$
  526.     { pop$
  527.       "english" language.state.test
  528.       "USenglish" language.state.test
  529.       or
  530.         { type "t" change.case$ }
  531.         { type }
  532.       if$
  533.     }
  534.   if$
  535. }
  536.  
  537. FUNCTION {format.tr.number}
  538. { type empty$
  539.     { "\Btxtechreplong{}" }
  540.     'type
  541.   if$
  542.   number empty$
  543.     { "english" language.state.test
  544.       "USenglish" language.state.test
  545.       or
  546.         { type empty$
  547.             { pop$ "\btxtechreplong{}" }
  548.             { "t" change.case$ }
  549.           if$
  550.         }
  551.         'skip$
  552.       if$
  553.     }
  554.     { number tie.or.space.connect }
  555.   if$
  556. }
  557.  
  558. FUNCTION {format.article.crossref}
  559. { key empty$
  560.     { journal empty$
  561.         { "need key or journal for " cite$ * " to crossref " * crossref *
  562.           warning$
  563.           ""
  564.         }
  565.         { "\Btxinlong{}\ " journal emphasize * }
  566.       if$
  567.     }
  568.     { "\Btxinlong{}\ " key emphasize * }
  569.   if$
  570.   " \cite{" * crossref * "}" *
  571. }
  572.  
  573. FUNCTION {format.crossref.editor}
  574. { editor #1 "{ll}{, jj}{, ff}{~vv}" format.name$ smallcaps
  575.   editor num.names$ duplicate$
  576.   #2 >
  577.     { pop$ " \btxetalshort{.}" * }
  578.     { #2 <
  579.         'skip$
  580.         { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
  581.             { " \btxetalshort{.}" * }
  582.             { " \btxandlong{}\ " * editor #2 "{ff}{~vv}{~ll}{, jj}" format.name$ smallcaps * }
  583.           if$
  584.         }
  585.       if$
  586.     }
  587.   if$
  588. }
  589.  
  590. FUNCTION {format.book.crossref}
  591. { volume empty$
  592.     { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
  593.       "\Btxinlong{}\ "
  594.     }
  595.     { "\Btxvolumelong{}" volume tie.or.space.connect
  596.       " \btxofserieslong{}\ " *
  597.     }
  598.   if$
  599.   editor empty$
  600.   editor field.or.null author field.or.null =
  601.   or
  602.     { key empty$
  603.         { series empty$
  604.             { "need editor, key, or series for " cite$ * " to crossref " *
  605.               crossref * warning$
  606.               "" *
  607.             }
  608.             { series emphasize * }
  609.           if$
  610.         }
  611.         { key emphasize * }
  612.       if$
  613.     }
  614.     { format.crossref.editor * }
  615.   if$
  616.   " \cite{" * crossref * "}" *
  617. }
  618.  
  619. FUNCTION {format.incoll.inproc.crossref}
  620. { editor empty$
  621.   editor field.or.null author field.or.null =
  622.   or
  623.     { key empty$
  624.         { booktitle empty$
  625.             { "need editor, key, or booktitle for " cite$ * " to crossref " *
  626.               crossref * warning$
  627.               ""
  628.             }
  629.             { "\Btxinlong{}\ " booktitle emphasize * }
  630.           if$
  631.         }
  632.         { "\Btxinlong{}\ " key emphasize * }
  633.       if$
  634.     }
  635.     { "\Btxinlong{}\ " format.crossref.editor * }
  636.   if$
  637.   " \cite{" * crossref * "}" *
  638. }
  639.  
  640. FUNCTION {article}
  641. { output.bibitem
  642.   format.authors "author" output.check
  643.   after.authors
  644.   format.title "title" output.check
  645.   new.block
  646.   crossref missing$
  647.     { journal 
  648.       title missing$
  649.         { emphasize }
  650.         'skip$
  651.       if$
  652.       "journal" output.check 
  653.       format.vol.num.pages output
  654.       format.date "year" output.check
  655.     }
  656.     { format.article.crossref output.nonnull
  657.       format.pages output
  658.     }
  659.   if$
  660.   new.block
  661.   note output
  662.   fin.entry
  663. }
  664.  
  665. FUNCTION {book}
  666. { output.bibitem
  667.   author empty$
  668.     { format.editors "author and editor" output.check }
  669.     { format.authors output.nonnull
  670.       crossref missing$
  671.         { "author and editor" editor either.or.check }
  672.         'skip$
  673.       if$
  674.     }
  675.   if$
  676.   after.authors
  677.   format.btitle "title" output.check
  678.   crossref missing$
  679.     { format.bvolume output
  680.       new.block
  681.       format.number.series output
  682.       new.sentence
  683.       publisher "publisher" output.check
  684.       address output
  685.     }
  686.     { new.block
  687.       format.book.crossref output.nonnull
  688.     }
  689.   if$
  690.   format.edition output
  691.   format.date "year" output.check
  692.   new.block
  693.   note output
  694.   fin.entry
  695. }
  696.  
  697. FUNCTION {booklet}
  698. { output.bibitem
  699.   format.authors output
  700.   after.authors
  701.   format.title "title" output.check
  702.   howpublished address new.block.checkb
  703.   howpublished output
  704.   address output
  705.   format.date output
  706.   new.block
  707.   note output
  708.   fin.entry
  709. }
  710.  
  711. FUNCTION {inbook}
  712. { output.bibitem
  713.   author empty$
  714.     { format.editors "author and editor" output.check }
  715.     { format.authors output.nonnull
  716.       crossref missing$
  717.         { "author and editor" editor either.or.check }
  718.         'skip$
  719.       if$
  720.     }
  721.   if$
  722.   after.authors
  723.   format.btitle "title" output.check
  724.   crossref missing$
  725.     { format.bvolume output
  726.       format.chapter.pages "chapter and pages" output.check
  727.       new.block
  728.       format.number.series output
  729.       new.sentence
  730.       publisher "publisher" output.check
  731.       address output
  732.     }
  733.     { format.chapter.pages "chapter and pages" output.check
  734.       new.block
  735.       format.book.crossref output.nonnull
  736.     }
  737.   if$
  738.   format.edition output
  739.   format.date "year" output.check
  740.   new.block
  741.   note output
  742.   fin.entry
  743. }
  744.  
  745. FUNCTION {incollection}
  746. { output.bibitem
  747.   format.authors "author" output.check
  748.   after.authors
  749.   format.title "title" output.check
  750.   new.block
  751.   crossref missing$
  752.     { format.in.ed.booktitle "booktitle" output.check
  753.       format.bvolume output
  754.       format.number.series output
  755.       format.chapter.pages output
  756.       new.sentence
  757.       publisher "publisher" output.check
  758.       address output
  759.       format.edition output
  760.       format.date "year" output.check
  761.     }
  762.     { format.incoll.inproc.crossref output.nonnull
  763.       format.chapter.pages output
  764.     }
  765.   if$
  766.   new.block
  767.   note output
  768.   fin.entry
  769. }
  770.  
  771. FUNCTION {inproceedings}
  772. { output.bibitem
  773.   format.authors "author" output.check
  774.   after.authors
  775.   format.title "title" output.check
  776.   new.block
  777.   crossref missing$
  778.     { format.in.ed.booktitle "booktitle" output.check
  779.       format.bvolume output
  780.       format.number.series output
  781.       format.pages output
  782.       address empty$
  783.         { organization publisher new.sentence.checkb
  784.           organization output
  785.           publisher output
  786.           format.date "year" output.check
  787.         }
  788.         { address output.nonnull
  789.           format.date "year" output.check
  790.           new.sentence
  791.           organization output
  792.           publisher output
  793.         }
  794.       if$
  795.     }
  796.     { format.incoll.inproc.crossref output.nonnull
  797.       format.pages output
  798.     }
  799.   if$
  800.   new.block
  801.   note output
  802.   fin.entry
  803. }
  804.  
  805. FUNCTION {conference} { inproceedings }
  806.  
  807. FUNCTION {manual}
  808. { output.bibitem
  809.   author empty$
  810.     { organization empty$
  811.         'skip$
  812.         { organization smallcaps output.nonnull
  813.           address output
  814.         }
  815.       if$
  816.     }
  817.     { format.authors output.nonnull }
  818.   if$
  819.   after.authors
  820.   format.btitle "title" output.check
  821.   author empty$
  822.     { organization empty$
  823.         { address new.block.checka
  824.           address output
  825.         }
  826.         'skip$
  827.       if$
  828.     }
  829.     { organization address new.block.checkb
  830.       organization output
  831.       address output
  832.     }
  833.   if$
  834.   format.edition output
  835.   format.date output
  836.   new.block
  837.   note output
  838.   fin.entry
  839. }
  840.  
  841. FUNCTION {mastersthesis}
  842. { output.bibitem
  843.   format.authors "author" output.check
  844.   after.authors
  845.   format.title "title" output.check
  846.   new.block
  847.   "\btxmastthesis{}" format.thesis.type output.nonnull
  848.   school "school" output.check
  849.   address output
  850.   format.date "year" output.check
  851.   new.block
  852.   note output
  853.   fin.entry
  854. }
  855.  
  856. FUNCTION {misc}
  857. { output.bibitem
  858.   format.authors output
  859.   title howpublished new.block.checkc
  860.   format.title output
  861.   howpublished new.block.checka
  862.   howpublished output
  863.   format.date output
  864.   new.block
  865.   note output
  866.   fin.entry
  867.   empty.misc.check
  868. }
  869.  
  870. FUNCTION {phdthesis}
  871. { output.bibitem
  872.   format.authors "author" output.check
  873.   after.authors
  874.   format.btitle "title" output.check
  875.   new.block
  876.   "\btxphdthesis{}" format.thesis.type output.nonnull
  877.   school "school" output.check
  878.   address output
  879.   format.date "year" output.check
  880.   new.block
  881.   note output
  882.   fin.entry
  883. }
  884.  
  885. FUNCTION {proceedings}
  886. { output.bibitem
  887.   editor empty$
  888.     { organization smallcaps output }
  889.     { format.editors output.nonnull }
  890.   if$
  891.   after.authors
  892.   format.btitle "title" output.check
  893.   format.bvolume output
  894.   format.number.series output
  895.   address empty$
  896.     { editor empty$
  897.         { publisher new.sentence.checka }
  898.         { organization publisher new.sentence.checkb
  899.           organization output
  900.         }
  901.       if$
  902.       publisher output
  903.       format.date "year" output.check
  904.     }
  905.     { address output.nonnull
  906.       format.date "year" output.check
  907.       new.sentence
  908.       editor empty$
  909.         'skip$
  910.         { organization output }
  911.       if$
  912.       publisher output
  913.     }
  914.   if$
  915.   new.block
  916.   note output
  917.   fin.entry
  918. }
  919.  
  920. FUNCTION {techreport}
  921. { output.bibitem
  922.   format.authors "author" output.check
  923.   after.authors
  924.   format.title "title" output.check
  925.   new.block
  926.   format.tr.number output.nonnull
  927.   institution "institution" output.check
  928.   address output
  929.   format.date "year" output.check
  930.   new.block
  931.   note output
  932.   fin.entry
  933. }
  934.  
  935. FUNCTION {unpublished}
  936. { output.bibitem
  937.   format.authors "author" output.check
  938.   after.authors
  939.   format.title "title" output.check
  940.   new.block
  941.   note "note" output.check
  942.   format.date output
  943.   fin.entry
  944. }
  945.  
  946. FUNCTION {default.type} { misc }
  947.  
  948. MACRO {jan} {"\btxmonjanlong{}"}
  949.  
  950. MACRO {feb} {"\btxmonfeblong{}"}
  951.  
  952. MACRO {mar} {"\btxmonmarlong{}"}
  953.  
  954. MACRO {apr} {"\btxmonaprlong{}"}
  955.  
  956. MACRO {may} {"\btxmonmaylong{}"}
  957.  
  958. MACRO {jun} {"\btxmonjunlong{}"}
  959.  
  960. MACRO {jul} {"\btxmonjullong{}"}
  961.  
  962. MACRO {aug} {"\btxmonauglong{}"}
  963.  
  964. MACRO {sep} {"\btxmonseplong{}"}
  965.  
  966. MACRO {oct} {"\btxmonoctlong{}"}
  967.  
  968. MACRO {nov} {"\btxmonnovlong{}"}
  969.  
  970. MACRO {dec} {"\btxmondeclong{}"}
  971.  
  972. MACRO {acmcs} {"ACM Computing Surveys"}
  973.  
  974. MACRO {acta} {"Acta Informatica"}
  975.  
  976. MACRO {cacm} {"Communications of the ACM"}
  977.  
  978. MACRO {ibmjrd} {"IBM Journal of Research and Development"}
  979.  
  980. MACRO {ibmsj} {"IBM Systems Journal"}
  981.  
  982. MACRO {ieeese} {"IEEE Transactions on Software Engineering"}
  983.  
  984. MACRO {ieeetc} {"IEEE Transactions on Computers"}
  985.  
  986. MACRO {ieeetcad}
  987.  {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
  988.  
  989. MACRO {ipl} {"Information Processing Letters"}
  990.  
  991. MACRO {jacm} {"Journal of the ACM"}
  992.  
  993. MACRO {jcss} {"Journal of Computer and System Sciences"}
  994.  
  995. MACRO {scp} {"Science of Computer Programming"}
  996.  
  997. MACRO {sicomp} {"SIAM Journal on Computing"}
  998.  
  999. MACRO {tocs} {"ACM Transactions on Computer Systems"}
  1000.  
  1001. MACRO {tods} {"ACM Transactions on Database Systems"}
  1002.  
  1003. MACRO {tog} {"ACM Transactions on Graphics"}
  1004.  
  1005. MACRO {toms} {"ACM Transactions on Mathematical Software"}
  1006.  
  1007. MACRO {toois} {"ACM Transactions on Office Information Systems"}
  1008.  
  1009. MACRO {toplas} {"ACM Transactions on Programming Languages and Systems"}
  1010.  
  1011. MACRO {tcs} {"Theoretical Computer Science"}
  1012.  
  1013. READ
  1014.  
  1015. STRINGS { longest.label }
  1016.  
  1017. INTEGERS { number.label longest.label.width }
  1018.  
  1019. FUNCTION {initialize.longest.label}
  1020. { "" 'longest.label :=
  1021.   #1 'number.label :=
  1022.   #0 'longest.label.width :=
  1023. }
  1024.  
  1025. FUNCTION {longest.label.pass}
  1026. { number.label int.to.str$ 'label :=
  1027.   number.label #1 + 'number.label :=
  1028.   label width$ longest.label.width >
  1029.     { label 'longest.label :=
  1030.       label width$ 'longest.label.width :=
  1031.     }
  1032.     'skip$
  1033.   if$
  1034. }
  1035.  
  1036. EXECUTE {initialize.longest.label}
  1037.  
  1038. ITERATE {longest.label.pass}
  1039.  
  1040. FUNCTION {begin.bib}
  1041. { preamble$ empty$
  1042.     'skip$
  1043.     { preamble$ write$ newline$ }
  1044.   if$
  1045.   "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
  1046. }
  1047.  
  1048. EXECUTE {begin.bib}
  1049.  
  1050. EXECUTE {init.state.consts}
  1051.  
  1052. ITERATE {call.type$}
  1053.  
  1054. FUNCTION {end.bib}
  1055. { newline$
  1056.   "\end{thebibliography}" write$ newline$
  1057. }
  1058.  
  1059. EXECUTE {end.bib}
  1060.